随之而来的问题就是，大量的技能，在有限的键位下，如何整合，才能减少宏的数量。
方法一：德鲁伊拥有多个形态，可以通过判定形态的条件，实现不同形态释放不同的技能，如
#showtooltip
/cast [stance:1]裂伤;[stance:2]斜掠;[stance:4]月火术;[nostance:1/2/4]回春术

对应的熊形态1释放裂伤，猫形态2释放撕碎，鸟形态4释放月火术，不在熊1、猫2、鸟4形态则释放回春术，是不是很屌？但细细回想，每个形态都有对应的独立主动作条啊，能放12个技能，直接将技能放进主动作条，不就可以了吗，要这个宏有毛用？
是的，要这个宏有屁用啊，所以大家看到类似于上面这个宏的整合宏，请无视！！！WOW不用宏都能玩，这样无脑的宏几乎没有意义。我们使用整合宏，目的是将各种需要使用条件的技能整合在一起，具有实用性，不是自以为是的个人高端主义。
熊专精直接给裂伤一个独立键位就可以了，但非熊专精，点了熊亲和，变形后，会需要狂暴回复回血，裂伤攒怒气；猫专精则可能多目标斜掠，最大化伤害、挂减速；鸟专精也需要多目标挂月火，最大化伤害，有时还需对焦点丢月火；奶专精及奶亲和天赋，则可能在人形态下，对友善目标回春、敌对目标月火。那么此时，上面那个无意义的宏修改下，就可以体现出宏的目的了，宏如下：
#showtooltip
/cast [stance:1]裂伤;[@mouseover,exists,stance:2][stance:2]斜掠;[mod:alt,@focus,harm,stance:4][@mouseover,exists,stance:4][stance:4]月火术;[@mouseover,exists,harm,nostance:1/2/4][harm,nostance:1/2/4]月火术;[@mouseover,exists,help,nostance:1/2/4][nostance:1/2/4]回春术
/cast 狂暴回复

方法二：通过专精判断来实行不同技能的整合宏，鸟、猫、熊、奶分别对应spec:1、2、3、4，化身天赋会取代狂暴、超凡之盟，所以宏选用狂暴、超凡之盟技能即可，如下 #showtooltip
/cast [spec:1]超凡之盟;[spec:2]狂暴;[spec:3]化身：乌索克的守护者(天赋，变形);[spec:4]化身：生命之树(天赋，变形)
/use 12
/use 14
/use 康的束缚石
上面列举的2个宏属抛砖引玉，希望大家能写出更多好用的宏：)

另有生活技能整合宏：能够大幅简化界面，但也只能放些生活技能或者玩具
左键钓鱼、右键炉石；alt加左键锻造、alt加右键工程；ctrl加左键急救、ctrl加右键考古；shift加左键烹饪、shift加右键烧火。可自行更改技能，也看修改为各种玩具、道具。 #showtooltip
/use [nomod,btn:1]钓鱼;[nomod,btn:2]炉石
/use [mod:alt,btn:1]锻造;[mod:alt,btn:2]工程学
/use [mod:ctrl,btn:1]急救;[mod:ctrl,btn:2]考古学
/use [mod:shift,btn:1]烹饪;[mod:shift,btn:2]烹饪用火

 

下面给出几个比较好的宏
焦点目标切换宏：尤其适合于22，自己给宏选一个喜欢的图标。
无焦点目标时：a.有目标，则将目标设为焦点；b.无目标，则将上一个目标设为焦点
有焦点目标时：a.有目标，焦点与目标互换；b.无目标，焦点与空目标互换，即选择焦点为当前目标，同时清除焦点
/cleartarget [target=target, dead]
/clearfocus [target=focus, dead]
/target focus
/cleartarget [target=focus, noexists]
/targetlasttarget
/focus target
/targetlasttarget
影遁潜行宏：绑定小玩具及回血道具
#showtooltip 影遁
/stopattack
/use [combat,nostealth]上层精灵的灵魂镜
/use [combat,nostealth]世界放大器
/cast [combat,nostealth]影遁
/use 永茂蕨叶
/cast [nocombat,nostealth]!潜行
/stopattack [stealth]
盾墙宏：盾墙绑定道具，在户外效果是杠杠的
#showtooltip [spec:2/3]生存本能;[spec:1/4]树皮术
/cast [spec:2/3]生存本能
/cast [spec:1/4]树皮术
/use 治疗石
/use 先知之手战旗
/use 觉醒教派战旗
/use 协同战旗
/use 新生
/cast 塞纳里奥结界

急奔宏：急奔不再解除定身效果，但利用取消变形解除定身，及急奔不占用公CD且强制变猫，可通过宏实现以前的效果。通常潜行下不需要解定身，非猫形态会强制变猫，所以宏限定在猫形态、非潜行时取消形态解除定身，然后激活急奔并强制变猫，但别手抽筋，不然会变人形态。
#showtooltip 急奔
/cancelform [stance:2,nostealth]
/cast 急奔

变形解定身宏：取消变形会产生公CD，无法无缝的猫变猫，熊变熊了，需要猫变熊，熊变猫转换。通过判断专精及形态实现鸟-猫，猫-熊，回春-熊的切换，因熊处于抗怪期间，不能随意变形，所以未加入宏。当然本宏属于废宏，将技能丢在相应的姿态同一个位置，能达到一模一样的效果。
#showtooltips
/cast [spec:1,nostance:4]枭兽形态;[spec:1,stance:4]熊形态(变形);[spec:2,nostance:2]猎豹形态(变形);[spec:2,stance:2]熊形态(变形);[spec:4,nostance:1]熊形态(变形);[spec:4,stance:1,@mouseover,exists][spec:4,stance:1]熊形态(变形);回春术

同层天赋切换宏：并绑定焦点、鼠标指向功能
#showtooltip
/cast [mod:alt,@focus,talent:4/1][@mouseover,exists,talent:4/1][talent:4/1,nomod]蛮力猛击;[mod:alt,@focus,talent:4/2][@mouseover,exists,talent:4/2][talent:4/2,nomod]群体缠绕;[talent:4/3]台风

缠绕/驱散双向判定宏：比较适合猫德，如果是其他专精，需要适应，毕竟读条技能和瞬发技能绑定到一个键位了
#showtooltip
/cast [mod:alt,@focus,harm][@mouseover,exists,harm][nomod,harm]纠缠根须;[@mouseover,exists,help,spec:1/2/3][spec:1/2/3]清除腐蚀;[@mouseover,exists,help,spec:4][spec:4]自然之愈

月火/回春双向判定宏：
#showtooltip
[mod:alt,@focus,harm][@mouseover,exists,harm][harm]月火术;[@mouseover,exists,help][]回春术

冲锋+斜掠宏：选定友善目标时，取消形态援护；敌对目标则组合键焦点、指向、选中冲锋，同时绑定了猫形态组合键焦点、指向、选中斜掠。如果选了熊亲和，可使用裂伤，没有则换成横扫，援护队友千万别添加鼠标指向功能，作为近战，鼠标太容易碰到队友了
这个宏的原理是利用了冲锋无公CD，8~25码距离，卡了一个近战技能。如果选择了鸟亲和，或者斜掠10码的PVP天赋，在二者交叉的距离内，会造成冲锋的CD浪费
#showtooltip 野性冲锋
/cancelform [help]
/use 11
/cancelform [help]
/cast [mod:alt,@focus] [@mouseover,exists] []野性冲锋
/stopattack [stealth]
/cast [stance:2,mod:alt,@focus][stance:2,@mouseover,exists][stance:2]斜掠;[stance:1]裂伤
/stopattack [stealth]

潜行斜掠/撕碎宏：作为猫德，如果还是个抽筋手，那么肯定喜欢潜行下狂点斜掠，如果点多了，那就悲催了，刚上的双倍斜掠很容易被普通斜掠顶掉。
下面这个宏，潜行下斜掠，出潜行了则撕碎，非常适合抽筋手。绑定了非战斗潜行，熊形态下狂暴回复，权当是甜头。
#showtooltips [nocombat]潜行;[stealth]斜掠;[stance:2]撕碎;[stance:1]裂伤
/cast [stance:1]狂暴回复
/cast [nocombat]!潜行
/targetenemyplayer [noharm]
/stopattack [stealth]
/cast [stealth]斜掠;[nostealth,stance:2,combat]撕碎;[stance:1]裂伤
/stopattack [stealth]

军团再临修改了化身效果，如果想击晕，必须先潜行，所以无论如何都需要一个独立的键位。 手巧的小德给潜行一个键位，进可打斜掠击晕，退可潜行走位。
手法差的朋友，直接潜行+斜掠绑定吧，抽筋手点击来击晕，宏如下
#showtooltips
/cast !潜行
/stopattack [stealth]
/cast [@mouseover,exists,stealth[stealth]斜掠
/stopattack [stealth]

相应的可以将潜行绑定到不同的技能下，如奶亲和的迅捷治愈，回春术等，勉强作为一个退的手段，宏如下
#showtooltips
/cast [@mouseover,exists[] 迅捷治愈
/cast !潜行

影遁可飞变鸟/不可飞潜行宏：用到的地方应该不会很多，所以键位可以丢的远一些，推荐F1、F2或者CTRL+1等不容易点错，又不是很频繁点击的键位
#showtooltip 影遁
/cast [combat]!影遁
/cast [nostance:3,nocombat,flyable]!旅行形态;!潜行

血爪猫治疗之触锁定形态宏：有效锁定猫形态，无迅捷时，或者抽筋手，都不会变人。人形态下，治疗之触释放不受影响
#showtooltip
/console autounshift 0
/cast [@mouseover,help,exists][]治疗之触
/console autounshift 1

还可以绑定战复
#showtooltip
/cast [@mouseover,noharm,dead][noharm,dead] 复生
/console autounshift 0
/cast [@mouseover,noharm,nodead][noharm,nodead] 治疗之触
/console autounshift 1

如果是打副本，把治疗之触都丢给T，通常目标的目标即是T，所以宏如下
#showtooltip
/console autounshift 0
/cast [@mouseover,help,exists][@targettarget,help,exists][]治疗之触
/console autounshift 1

鼠标指向宏：很单一的治疗、伤害什么的
#showtooltip
/cast [@mouseover,help,exists][]回春术
#showtooltip
/cast [mod:alt,@focus] [@mouseover,exists] []月火术

焦点施法宏：最后一个条件中添加NOMOD，避免焦点/鼠标指向目标，突然消失时，技能打给当前目标。后面还有个三形态合一的打断宏  
#showtooltip
/use [mod:alt,@focus] [@mouseover,exists] [nomod]迎头痛击
#showtooltip
/use [mod:alt,@focus,stance:1/2][@mouseover,exists,stance:1/2][nomod,stance:1/2]迎头痛击;[mod:alt,@focus,stance:4][@mouseover,exists,stance:4][nomod,stance:4]日光术

熊德一键宏：
#showtooltips
/startattack
/castsequence reset=3 裂伤,痛击(野性、守护),月火术(月光),铁鬃,横扫

但尝试了之后，在抽筋手下，这个宏基本打不出触发的裂伤，不过裂伤、月火手动，只打痛击、横扫的话，倒还不错，省了一个键位，将精力放在走位、看技能方面，宏如下 #showtooltips
/castsequence reset=2.5 痛击(野性、守护),横扫,横扫

华丽的基维斯宏：请各位推荐好玩的玩具
/use 希尔瓦娜斯的音乐盒
/use 世界缩小器
/use 守备官盔甲打磨包
/use 黑火匕首
/use 炽燃之翼
/use 德鲁伊和牧师雕像组
/use 古克罗克的甲壳
/use 上层精灵的灵魂镜
/use 山丘之王的圣杯
/use 纳鲁来临
/use 巴肖克之魂
/use 圣甲虫风暴坠饰
/use 基维斯
/use 星图
/use 暗月哨子
/use 泡泡棒
/use 熊猫人焰火发射器
/use 米露恩的召唤