看到有朋友说一个个复制太麻烦，心疼，于是花了大半天学了下插件开发，给大家做了个插件导入。

下载CJTMacro.zip文件解压到 wow/Interface/AddOns 中即可。



打开宏编辑菜单即可看到新按钮，选中要用的宏，点导入通用宏或者导入当前角色专用宏即可。(别点多了，会重复复制的)

宏本身我会根据兄弟们的意见修改，插件到时候也会更新。还有今天没来得及回答的宏问题，明天尽量给解答。

-------------------9.19更新
开门见山，楼主的键位图
f1 f2 f3 f4 f5 f6 f7 f8 f9 f10 f11 f12
1 2 3 4 5 6 7 8 9 0 - q(最后一个键被改成q，因为按着方便)

是的，只有两排按键。两排按键怎么放下海量的技能，专业和玩具？客官倒杯茶慢慢看来。

首先楼主把技能分作3种状态：作战状态，平常状态，按住ctrl/alt状态

分开列出来就是这样

作战状态：作战状态保持所有作战用得到的技能出现
1眼镜蛇射击 2凶暴野兽 3杀戮爆发 4弹幕/黑鸦 5打断 6灵龟守护 7震荡射击 8意气风发 9橙戒饰品 0假死 -装死 q多重
f1宠物宏 f2爆发宏 f3逃脱 f4猎豹守护 f5照明弹 f6药水 f7绷带 f8荣誉勋章 f9宠物技能 f10觉醒火盆 f11鱼竿切换 f12暗月的凝视

平常状态：平常状态保证所有非战斗常用技能出现
1坐骑 2拾取器 3杀戮爆发 4裁缝 5工程 6考古勘测 7钓鱼 8低语水晶 9亢奋强化符文 0食物 -飞行管理员的哨子 q暗月大炮
f1宠物宏 f2爆发宏 f3逃脱 f4猎豹守护 f5照明弹 f6烹饪 f7绷带 f8炉石 f9达拉然炉石 f10德拉诺虫洞 f11鱼竿切换 f12侏儒军刀

按住ctrl/alt状态：此状态放入不那么常用但偶尔用到的技能道具
1坐骑 2拾取器 3杀戮爆发 4裁缝 5工程 6灵龟守护 7震荡射击 8银色小步兵 9随机小宠物 0精华交换器 -装死 q移动邮箱
f1宠物宏 f2爆发宏 f3滑翔披风 f4布林顿 f5移动银行 f6烹饪 f7绷带 f852区传送器 f9诺森德传送器 f10潘达利亚虫洞 f11暗流 f12基维斯

上面并没有包含所有技能？慢慢看，一个一个讲

首先讲猎人最精品的宏，宠物宏。
宠物宏我放在F1,为什么不放在123的位置？因为战斗中宠物不是个频繁按的键，但又很关键，放在容易按到，又不频繁的F1很合适。
F1宠物宏 ...
#showtooltip
/castsequence [@pet,dead] 复活宠物; [btn:2,pet] 解散宠物; [btn:2]召唤宠物 4;[nopet,btn:3]召唤宠物 5; [nopet,mod:alt]召唤宠物 3; [nopet,mod:ctrl]召唤宠物 2;[nopet]reset=2 召唤宠物 1,复活宠物;reset=2 治疗宠物, 解散宠物
/use 凤凰之心

宠物宏包含了除了喂食以外的所有功能，当然我知道你们也不喂。

具体解析如下：

当你没有宠物的时候，按一下，召唤宠物1
当你宠物活着的时候，按一下，治疗宠物
当你宠物活着的时候，右键或者着按两下，解散宠物
当你宠物死亡的时候，按一下，复活宠物，有凤凰之心时秒活，没有时读条活
当你宠物死亡的时候，而且尸体被你拖没了的时候，按两下，复活宠物

按右键，召唤宠物4；按中键，召唤宠物5；按住alt，召唤宠物3；按住ctrl，召唤宠物2；

总之看了宠物宏的功能之多，它独占一个键不亏。

接下来讲战斗循环1，2，3，4，算上多重q和打断5，一共6个键

眼镜蛇射击是战斗中的高频技能，开怪技能等等，放在1键当得起。
坐骑是非战斗最常用键，两者搭配相得益彰。
1眼镜蛇射击 ...
#showtooltip [combat][harm,nodead]眼镜蛇射击;炉石天马
/stopmacro [channeling]
/cast [harm,nodead][combat] 眼镜蛇射击;
/startattack [combat,harm]
/stopmacro [harm,nodead][combat]
/use [btn:3]猩红水黾;[btn:2]雄壮远足牦牛;[mod:ctrl]X-53型观光火箭
/run C_MountJournal.SummonByID(0)

首先当你按下这个键时不会打断吟唱，读弹幕时错按到也不影响。
然后在打出一发眼镜蛇的同时带出自动攻击

另一方面，在脱战的情况下，此宏自动变为万能坐骑宏
直接点它的功能和随机偏好坐骑一致。
在能飞的地方点，招随机偏好的飞行坐骑。
在不能飞的地方，招随机偏好的飞行和地面坐骑。
在水面，招随机偏好的水黾。
在水中，招随机偏好海龟水母。

同时还有右键招牦牛卖东西，中键招水黾涉水，ctrl招火箭。

这个宏为什么没有加自动误导，因为这宏248字，字数快满了，把误导丢到2号技能凶暴野兽中，所以请继续阅读下一个。

凶暴野兽是战斗高频技能之一，尤其是经常会闪一下，给你再来一次的机会，所以基本就是按按按按按。
而远程拾取器呢，你打完以后一定会强迫症一样的按按按按按的，尤其是怪死得比较分散的时候。
所以这个2号键呢，打怪你就一直按吧。
2凶暴野兽 ...
#showtooltip
/stopmacro [channeling]
/use [noharm][dead]远程拾取器
/stopmacro [noharm][dead]
/协助 [help]
/startattack
/petattack
/use 凶暴野兽
/cast [@focus,help] [@targettarget,help] [@pet,exists] 误导

技能解析：

目标是敌人的时候，放凶暴野兽
同时，自动给焦点，或者目标的目标，或者你的bb挂误导。
开启自动攻击，宠物攻击，战斗正式打响。

目标死了，或者把目标取消掉，就是拾取。当然，工程专用。非工程的话，请把拾取器换成拾回，捡东西会慢点。

3号，杀戮爆发宏，这个宏有两种形态，一种是随时爆发，一种是在副本里默认不爆发，设了焦点才爆发。
3杀戮命令 ...
#showtooltip
/use [spec:1]杀戮命令;[spec:2]奇美拉射击
/use [combat,spec:1]狂野怒火;[combat,spec:2]急速射击
/use [combat] 奥术洪流;
/use [combat]野性守护
/use [combat]13


当你按3了，那就是一套带走对面，因为你按下这个键的同时会带出来4个瞬发技能:狂野怒火,野性守护,奥术洪流,饰品技能
这几个瞬发技能实际可以绑在任何键上，也可以分开放在多个键上，见仁见智。不过我的杀戮键刚好空虚，那就让杀戮带走敌人吧。

为什么会出现奇美拉和急速这种东西？其实这套宏在6.0的时候我是兽王射击双天赋皆可用的，所以保留了下来，至于如今的射击，由于我专心的养兽王神器，并不知道情况如何。

后来觉得有时候在副本里还要飚个dps什么的，大招不能随便就放了呀，于是加上个开关，在副本里的话，如果你不设个焦点，就不会自动用掉红人，野性和饰品。
3杀戮命令带开关 ...
#showtooltip
/use [spec:1]杀戮命令;[spec:2]奇美拉射击
/equip [noequipped:远程武器]泰坦之击
/use [combat] 奥术洪流;
/stopmacro [group,nofocus]
/use [combat,spec:1]狂野怒火;[combat,spec:2]急速射击
/use [combat]野性守护
/use [combat]13

当然，这个键的非战斗状态和ctrl alt状态我没设置，主要是想表达，哼，看我还有多的空间可以放更多技能。
追加，为了配合7号键在钓鱼时自动切到鱼竿，杀戮之后会帮你自动切回泰坦之击。

4号位，这个就是，你点了弹幕就是弹幕，点了黑鸦就黑鸦，点了乱射，就是乱射的开关。而脱战的时候，就是你的第一专业。
弹幕黑鸦乱射 ...
#showtooltip
/use [nocombat,noharm]裁缝;[talent:6/1]夺命黑鸦;[talent:6/2]弹幕射击;[talent:6/3]乱射

不要问我为什么是裁缝，懒人好意思回答你？

5号位，神奇双打断
反制射击胁迫 ...
#showtooltip
/use [nocombat,noharm]工程学
/castsequence [@focus,harm] [@target,harm] reset=24 反制射击,胁迫

有焦点打断焦点，没焦点打断目标。
默认是反制，用掉反制以后是胁迫，反制冷却好又变成反制。
神奇吧，今天刚写的，大家试试。

脱战后是第二专业，我大工程，不服来辩。

Q键，误导多重，开怪群攻。
q多重射击 ...
#showtooltip
/use [nocombat,noharm,mod]移动邮箱;[nocombat,noharm]暗月大炮
/stopmacro [nocombat,noharm]
/use 多重射击
/use [@target,help] [@targettarget,help] [@focus,help] [@pet,exists] 误导
/a [@target,help]

猎人上去拉怪，嗯，这就是给你拉怪的。
2键也是误导进攻，但连你的bb都一起上了。
这个误导给T，多重引过来，宝宝被动不要上，过来按2让宝宝上。

当然，遇到群怪直接上也是按这个，qqqqq,看我瑞文光速q

然后脱战是暗月大炮，不能飞的时候的跑路神器，配合滑翔机服用。
按住ctrl或者alt移动邮箱，又是我大工程的福利。

上面就把猎人输出的技能讲完了，什么，居然连上打断有6个，要知道lol连大招才4个，就不能让一个技能有两种效果吗？一个主动技带个被动效果不就完了，暴雪还得加油。

6号位是保命技灵龟守护
6灵龟守护 ...
#showtooltip
/cancelaura [combat]灵龟守护
/use [combat][mod:alt] 灵龟守护
/use [nocombat,btn:2]考古学;[nocombat]勘测

这个键要注意只按一下，因为再按一下取消灵龟buf。
这个设定我觉得还挺重要，因为我经常遇到去右上角想把buf点掉，但被各种插件挡住了右上角的情况。
灵龟取消后，加血还会持续，所以技能躲完尽管放心取消。

在脱战情况下，这个键是勘测，右键是考古，因为勘测在挖掘场是高频技能，占个数字键应该的，甚至可以和4，5号键换个位置

7号技能经过了加强，把鱼竿，钓鱼和震荡配合在了一起
7震荡射击 ...
#showtooltip
/equip [equipped:远程武器,nocombat,nomod][equipped:远程武器,combat,mod]幽光鱼竿
/castsequence [combat][mod]震荡射击;reset=0 钓鱼,暗流

钓鱼某些时候是常用技能，震荡射击是pvp的常用技能，他俩合用一个键，我觉得可以。
鱼竿跟钓鱼完美搭配，钓鱼之前如果发现没装备鱼竿，自动装上再钓。
连按两下是鱼竿技能暗流，而且是保证装上鱼竿并使用暗流。
非战斗状态，按下ctrl/alt也可以打出震荡，在抓某些低级宝宝但不想造成伤害的情况下可以用，最后加上/stopattack 停止自动攻击，用得更安心
战斗状态下，按下ctrl/alt也可以切到鱼竿，万一你想打不过跳水逃走也完全没问题。

8号加血，战前可以上buf
8意气风发 ...
#showtooltip [mod]银色小步兵;[combat]意气风发;奥拉留斯的低语水晶
/use [combat,nomod]意气风发;[nomod]奥拉留斯的低语水晶
/sp [mod]银色小步兵

showtooltip后面跟一串是因为召唤小宠物的命令sp不支持自动显示图标。
战斗时意气风发是常用技能，给个8。 战前水晶可以换成其他buf。
小步兵是个低频技能，按住ctrl或者alt才会出现，基维斯冷却的时候用用。至于小宠物，后面有更好的宏。

9号键在6.0的时候一直是我的神戒，群兽这个技能是个瞬发，可以绑在1，2，3，4任意一个键上，之前我一直绑4号位，弹幕或者黑鸦带出去。
但很多时候觉得可惜，毕竟3分钟冷却，暂时给你个键留一留，万一队友有射击生存，打boss我也不能太难看吧。
9群兽奔腾 ...
#showtooltip [combat]群兽奔腾;[nomod]亢奋强化符文;哨兵之友
/use [combat]群兽奔腾;[nomod]亢奋强化符文
/rfp [nocombat,mod]

亢奋强化符文这东西，随便换成什么buf药品道具吧
战前点，是buf,战斗中是群兽大招
按住mod是好东西，随机招出一个你偏爱的小宠物

0键，假死宏，以前有什么宠物援护自己假死，给自己加血假死，我觉得关系不大，直接死好了，其他技能有键，有需求多按一下好了。
0假死 ...
#showtooltip
/use [combat]假死;[mod]精华交换器;风干鲭鱼丝

战斗中按一下是假死，战斗外是吃食，会显示食物数量。
按住ctrl或者alt，是你们最近喜欢玩的精华交换器

猎人自己假死了，宠物也得有个键，这两个还不能共用一键，万一你想把仇恨转给bb呢
-装死 ...
#showtooltip
/use [combat][mod]装死;飞行管理员的哨子

注意装死再点一下就是唤醒，或者脱战完按住ctrl或alt唤醒。
脱战状态是当前版本神器哨子。

接下来是上排的宏，上排并非没有下排重要，上排前4的位置和下排前6都比较常用。

因为有时候想在1234键里把大招都去掉，专门给个键出来放大招，于是在仅次于宠物的远手位置放了个大招键
F2大招宏 ...
#showtooltip
/use [spec:1]狂野怒火;[spec:2]急速射击
/use 野性守护
/use 群兽奔腾
/use 13

一键开兽王的所有大招，瞬间爆炸。注意饰品用的是上面那个。什么，你两个饰品都有技能，那请加上一行/use 14

F3逃脱滑翔机，因为逃脱是战斗不战斗都会用的技能，所以独占一键。
F3逃脱 ...
#showtooltip
/use [mod][btn:2]15;逃脱

搭配滑翔机或者风筝，右键或者按住ctrl/alt都触发滑翔机，因为滑翔机可能会在跳的时候第一时间点出来，感觉还是右键方便点。

F4留给了猎豹，是个猎豹氮气双加速宏，类似上面的双打断，加速又是个战不战都会用的技能，所以只在安住ctrl/alt的时候多加了个布林顿
F4猎豹守护 ...
#showtooltip
/castsequence [nomod]reset=120 6,猎豹守护;布林顿5000

这个宏点一下是用氮气腰带加速，在点完腰带的120秒内再点，是猎豹加速，120秒后氮气好了，又变成氮气。
安住ctrl/alt是布林顿。
不过目前这个宏有个问题，就是战场的时候，腰带是不让用的，我希望能改成战场内只用猎豹，战场外猎豹腰带都支持。如果改好了，我会更新到这里。

F5照明弹，用得少，但pvp或者雷施这种时候会用，战不战都需要，按住ctrl/alt配上工会银行
F5照明弹 ...
#showtooltip
/use [mod]移动银行;照明弹

你问为什么公会银行是我的高频技能？哈，我自己一个工会，银行的格子全是我的。

F6神奇战斗药品宏
F6药品 ...
#showtooltip [combat]治疗滋补剂;烹饪
/use [combat]治疗石;[btn:2]永恒炭炉;[btn:3]魔焰营火;烹饪
/use [combat]粒子护盾
/use [combat]治疗滋补剂

战斗时会显示你的药水数量，点一下吃。
但吃的时候有学问，会先吃最不值钱的术士糖，没糖吃护盾，没护盾才吃药水。
非战斗状态右键中间是生不同的火，左键做食物。

F7绷带优先顺序，焦点友军加焦点，目标友军加目标，不是就绷带自己
F7绷带急救 ...
#showtooltip
/use [@focus,help] [@target,help] [combat,@player][mod]丝纹绷带;急救;

非战斗是急救

F8是PVP章带了两个门
F8荣誉勋章 ...
#showtooltip
/use [combat]荣誉勋章;[mod]空间撕裂器 - 52区;虚灵之门

用虚灵之门或者旅店老板女儿可以少占一格背包。

F9战斗时是当前宠物的特技，不战斗又是两个门
F9宠物特技 ...
#showtooltip
/use [nocombat,nomod]达拉然炉石;[nocombat]虫洞生成器：诺森德;[pet:灵魂兽,@target,help][pet:灵魂兽,@player]灵魂治愈;[pet:魁麟,@target,help][pet:魁麟,@focus,help]永恒守护者;[pet:熔岩犬]远古狂乱;

当你带的灵魂兽时，是按目标友军和自己的顺序放治疗
当你带魁麟是复活，复活优先复活目标，其次复活焦点。有时候战斗中找不到要复活的人也很糟心，一发焦点搞定
带熔岩犬是嗜血。

F10复活，战斗中找机会丢一个在自己脚下，团灭了会复活你。注意这东西进战斗前用不起作用。
F10觉醒火盆 ...
#showtooltip
/use [combat]觉醒火盆;[nocombat,mod]虫洞生成器：潘达利亚;[nocombat]虫洞离心机

也是搭配了两个门，唉，学工程就是为了不求法师开门。

F11钓鱼神器
F11幽光鱼竿 ...
#showtooltip
/equip [equipped:远程武器,nomod]幽光鱼竿;[nomod]泰坦之击
/use [mod]暗流

专门拿一个键来一键切换武器和鱼竿，战斗不战斗用着都很爽，水里跑得快，骑坐骑进水可以在坐骑上切，普通坐骑全变成水中坐骑了。
按住ctrl/alt是鱼竿技能

最后一个，是几个小玩具集合
F12暗月的凝视 ...
#showtooltip
/use [combat]暗月的凝视;[mod]基维斯;终极版侏儒军刀

非战斗是军刀，群活被砍以后，这个还是有用的。ctrl/alt是基维斯
战斗中最后没什么需要放的技能了，想到再改，放了个暗月的凝视，遥想当年猎人有标记的日子，这个可以替代标记，指挥队伍优先打哪个怪的时候，还算有点用。

最后还是给个隐藏福利
拯救世界的宏 ...
/join 大脚世界频道
/stopmacro [btn:1]
/leave 大脚世界频道
左键加入聊天，右键退出聊天，还你一片清净